G1 CALCULATION GROUP Control group Correlation matrix A factor 
DA CALC NG=4 
MATRICES 
A Lo 2 2 Fixed 
C Lo 2 2 Free 
E St 2 2 Free 
H Fu 1 1 
begin algebra; 
X = A*A' ; 
Y = C*C' ; 
Z = E ; 
end algebra; 
COMPUTE \stnd( X+Y+Z| H@X+Y _ 
               H@X+Y| X+Y+Z) ;
Matrix H .5 
Matrix A 0 0 0  
Matrix C .8 .8 .8
Matrix E .5
Option RS SE 
End 

G2 CALCULATION GROUP Clinical group Correlation matrix A factor 
DA CALC 
MATRICES 
A Lo 2 2 = A1 
C Lo 2 2 = C1 
E St 2 2 = E1 
H Fu 1 1 ! .5 
begin algebra; 
X = A*A' ; 
Y = C*C' ; 
Z = E ; 
end algebra; 
COMPUTE \stnd( X+Y+Z| H@X+Y _ 
               H@X+Y| X+Y+Z) ; 
Matrix H .5 
Option RS SE 
End 

Correlated liability model: control group data 
Data NI=6
ordinal fi=control.dat
Labels age1 age2 sex1 sex2 type dummy
Definition_variables age1 age2 sex1 sex2 type /
matrices 
i iden 1 1 
r full 4 4 =%e1 ! correlation matrix A1B1A2B2 
A Full 1 4 ! matrix for age definition variable
S Full 1 4 ! matrix for sex definition variable
L Full 1 4 ! estimated threshold for A 
O Full 1 4 ! age difference in threshold
D Full 1 4 ! sex difference in threshold
M Full 1 1 ! mean of dummy variable
V Full 1 1 ! variance of dummy variable
J Full 4 1 ! for extracting right part of K 
z zero 1 1 
begin algebra ; 
T = L+(A.O)+(S.D);	! Threshold = estimated threshold + (age * age 					     	  difference in threshold) + (sex * sex difference in 				  threshold)
K =  	 \muln(r_t_t_(i|i|i|i)) _   	! 1 (expected probability of 0000)
       \muln(r_t_t_(i|z|i|i)) _  	! 2 (expected probability of 0100)
       \muln(r_t_t_(i|i|i|z)) _  	! 3 (expected probability of 0001)
       \muln(r_t_t_(z|i|i|i)) _  	! 4 (expected probability of 1000)
       \muln(r_t_t_(i|i|z|i)) _  	! 5 (expected probability of 0010)
	 \muln(r_t_t_(z|z|i|i)) _ 	! 6 (expected probability of 1100)
       \muln(r_t_t_(i|i|z|z)) _ 	! 7 (expected probability of 0011)
       \muln(r_t_t_(i|z|i|z)) _ 	! 8 (expected probability of 0101)
       \muln(r_t_t_(z|i|i|z)) _ 	! 9 (expected probability of 1001)
       \muln(r_t_t_(i|z|z|i)) _ 	! 10 (expected probability of 0110)
       \muln(r_t_t_(z|z|i|z)) _ 	! 11 (expected probability of 1101)
       \muln(r_t_t_(i|z|z|z)) _ 	! 12 (expected probability of 0111)
       \muln(r_t_t_(z|i|z|i)) _ 	! 13 (expected probability of 1010)
	 \muln(r_t_t_(z|z|z|i)) _ 	! 14 (expected probability of 1110)
       \muln(r_t_t_(z|i|z|z)) _ 	! 15 (expected probability of 1011)
       \muln(r_t_t_(z|z|z|z))  ;  	! 16 (expected probability of 1111)
end algebra ; 
Matrix J 1 1 1 1
Matrix M 0
Matrix V .159154943
Matrix L 2.0 1.5 2.0 1.5
Matrix O -.05 -.05 -.05 -.05
Matrix D -.05 -.05 -.05 -.05
Specify L 20 21 20 21  ! threshold for A sib 1; threshold for B sib 1; threshold for A sib 2; threshold for B sib 2; 
Specify O 30 31 30 31
Specify D 40 41 40 41
SP A age1 age1 age2 age2; ! age for sib 1; age for sib 1; age for sib 2; age for sib 2;
SP S sex1 sex1 sex2 sex2; ! age for sib 1; age for sib 1; age for sib 2; age for sib 2;
SP J -5 0 -5 0;
Means M;
Covariance V;
Weight (\part(K,J)) /
option RS  
end 

Correlated liability model: inefficient approach; clinical group data 
Data NI=6
ordinal fi=clinical.dat
Labels age1 age2 sex1 sex2 type dummy
Definition_variables age1 age2 sex1 sex2 type /
matrices 
i iden 1 1 
r full 4 4 =%e2 ! correlation matrix A1B1A2B2 
A Full 1 4 ! matrix for age definition variable
S Full 1 4 ! matrix for sex definition variable
L Full 1 4 =L3! estimated threshold for A 
O Full 1 4 =O3! age difference in threshold
D Full 1 4 =D3! sex difference in threshold
M Full 1 1 ! mean of dummy variable
V Full 1 1 ! variance of dummy variable
J Full 4 1 ! for extracting right part of K 
z zero 1 1 
b full 1 1 ! ascertainment parameter for illicit drug dependence
c full 1 1 free ! ascertainment parameter for alcohol dependence 
begin algebra ;
G = B + C; 
T = L+(A.O)+(S.D);
K =   
       b.(\muln(r_t_t_(i|z|i|i))) _  ! 2 (expected probability of 0100)
       c.(\muln(r_t_t_(z|i|i|i))) _  ! 4 (expected probability of 1000)
	 g.(\muln(r_t_t_(z|z|i|i))) _  ! 6 (expected probability of 1100)
       b.(\muln(r_t_t_(i|z|i|z))) _  ! 8 (expected probability of 0101)
       c.(\muln(r_t_t_(z|i|i|z))) _  ! 9 (expected probability of 1001)
       b.(\muln(r_t_t_(i|z|z|i))) _  ! 10 (expected probability of 0110)
       g.(\muln(r_t_t_(z|z|i|z))) _  ! 11 (expected probability of 1101)
       b.(\muln(r_t_t_(i|z|z|z))) _  ! 12 (expected probability of 0111)
       c.(\muln(r_t_t_(z|i|z|i))) _  ! 13 (expected probability of 1010)    
	 g.(\muln(r_t_t_(z|z|z|i))) _  ! 14 (expected probability of 1110)
       c.(\muln(r_t_t_(z|i|z|z))) _  ! 15 (expected probability of 1011)
       g.(\muln(r_t_t_(z|z|z|z)))  ; ! 16 (expected probability of 1111)
Y = \sum(K);
U = Y_Y_Y_Y_Y_Y_Y_Y_Y_Y_Y_Y;
N = (K%U);
end algebra ; 
Matrix J 1 1 1 1
Matrix M 0
Matrix V .159154943
matrix b 1 
matrix c .5
SP A age1 age1 age2 age2; ! age for sib 1; age for sib 1; age for sib 2; age for sib 2;
SP S sex1 sex1 sex2 sex2; ! age for sib 1; age for sib 1; age for sib 2; age for sib 2;
SP J -5 0 -5 0;
Means M;
Covariance V;
Weight (\part(N,J)) /
Option func=.000001 
Option RS  
Option Th=-20
End