G1 CALCULATION GROUP Control Correlation matrix A factor 
DA CALC NG=6 
MATRICES 
A Lo 1 1 Fixed 
C Lo 1 1 Free 
H Fu 1 1
I id 1 1 
begin algebra; 
X = A*A' ; 
Y = C*C' ; 
end algebra; 
COMPUTE I|H@X+Y_ 
        H@X+Y|I;
Matrix A 0
Matrix H .5
Option RS 
End 

G2 CALCULATION GROUP Clinical Correlation matrix A factor 
DA CALC 
MATRICES 
A Lo 1 1 =A1 
C Lo 1 1 =C1 
H fu 1 1 
I id 1 1 
begin algebra; 
X = A*A' ; 
Y = C*C' ; 
end algebra ; 
COMPUTE I|H@X+Y_ 
        H@X+Y|I ; 
Matrix H .5 
Option RS 
End 

G3 CALCULATION GROUP Control Correlation matrix B factor 
DA CALC 
MATRICES 
A Lo 1 1 Fixed 
C Lo 1 1 Free 
H Fu 1 1
I id 1 1 
begin algebra; 
X = A*A' ; 
Y = C*C' ; 
end algebra; 
COMPUTE I|H@X+Y_ 
        H@X+Y|I;
Matrix H .5
Matrix A 0
Option RS 
End 

G4 CALCULATION GROUP Clinical Correlation matrix B factor 
DA CALC 
MATRICES 
A Lo 1 1 =A3 
C Lo 1 1 =C3 
H fu 1 1 
I id 1 1 
begin algebra; 
X = A*A' ; 
Y = C*C' ; 
end algebra ; 
COMPUTE I|H@X+Y_ 
        H@X+Y|I ; 
Matrix H .5 
Option RS 
End 

Epiphenomena model - fit model to Control A/D data 
Data NI=6
ordinal fi=control.dat
Labels age1 age2 sex1 sex2 type dummy
Definition_variables age1 age2 sex1 sex2 type /
Matrices  
A Full 2 2 =%E1 ! corr between A factors 
B Full 2 2 =%E3 ! corr between B factors 
P Full 1 1 free ! probability of being comorbid given A 
R Full 1 1 free ! probability of being comorbid given B 
O Full 1 2 ! matrix for age definition variable
M Full 1 2 ! matrix for sex definition variable
T Full 1 2 ! Estimated Threshold for A 
Q Full 1 2 ! age difference in threshold for A
X Full 1 2 ! sex difference in threshold for A
U Full 1 2 ! Estimated Threshold for B 
S Full 1 2 ! age difference in threshold for B
Y Full 1 2 ! sex difference in threshold for B
V Full 1 1 ! variance of dummy variable
L Full 4 1 ! for extracting right part of K
W Full 1 1 ! 0 + + These are to control integral type  
Z Full 1 1 ! 1 - - 
Begin Algebra; 
C = \muln((A_(T+(O.Q)+(M.X))_(T+(O.Q)+(M.X))_Z|Z)) ;    ! lower/lower A
D = \muln((A_(T+(O.Q)+(M.X))_(T+(O.Q)+(M.X))_Z|W)) ;    ! lower/upper A
E = \muln((A_(T+(O.Q)+(M.X))_(T+(O.Q)+(M.X))_W|Z)) ;    ! upper/lower A
F = \muln((A_(T+(O.Q)+(M.X))_(T+(O.Q)+(M.X))_W|W)) ;    ! upper/upper A
G = \muln((B_(U+(O.S)+(M.Y))_(U+(O.S)+(M.Y))_Z|Z)) ;    ! lower/lower B
H = \muln((B_(U+(O.S)+(M.Y))_(U+(O.S)+(M.Y))_Z|W)) ;    ! lower/upper B
I = \muln((B_(U+(O.S)+(M.Y))_(U+(O.S)+(M.Y))_W|Z)) ;    ! upper/lower B
J = \muln((B_(U+(O.S)+(M.Y))_(U+(O.S)+(M.Y))_W|W)) ;    ! upper/upper B
K =	C.G_ 													! 1 (expected probability of 0000)
	C.I.(Z-R)_												! 2 (expected probability of 0100)
	C.H.(Z-R)_												! 3 (expected probability of 0001)
	E.G.(Z-P)_												! 4 (expected probability of 1000)
	D.G.(Z-P)_												! 5 (expected probability of 0010)
	E.I + E.G.P + C.I.R_										! 6 (expected probability of 1100)
	D.H + D.G.P + C.H.R_										! 7 (expected probability of 0011)
	C.J.(Z-R).(Z-R)_											! 8 (expected probability of 0101)
	E.H.(Z-P).(Z-R)_											! 9 (expected probability of 1001)
	D.I.(Z-P).(Z-R)_											! 10 (expected probability of 0110)
	E.J.(Z-R) + E.H.P.(Z-R) + C.J.R.(Z-R)_							! 11 (expected probability of 1101)
	D.J.(Z-R) + D.I.P.(Z-R) + C.J.R.(Z-R)_							! 12 (expected probability of 0111)
	F.G.(Z-P).(Z-P)_											! 13 (expected probability of 1010)
	F.I.(Z-P) + F.G.P.(Z-P) + D.I.R.(Z-P)_							! 14 (expected probability of 1110)
	F.H.(Z-P) + F.G.P.(Z-P) + E.H.R.(Z-P)_							! 15 (expected probability of 1011)
	F.J + F.H.P + F.I.P + F.G.P.P + D.J.R + D.I.P.R + E.J.R + E.H.P.R + C.J.R.R;	! 16 (expected probability of 1111)
End algebra;
Matrix L 1 1 1 1
Matrix V .159154943
Matrix P .5
Matrix R .5
Matrix W 0
Matrix Z 1
Specify T 100 100
Specify Q 101 101
Specify X 102 102
Specify U 103 103
Specify S 104 104
Specify Y 105 105
Matrix T 1.5 1.5 
Matrix U 1.5 1.5
Specify O age1 age2;
Specify M sex1 sex2;
Specify L -5 0 -5 0;
Means W;
Covariance V;
Weight (\part(K,L)) /
Bound 0 1 3 4
Option RS 
End 

Epiphenomena model - fit model to Clinical A/D data 
Data NI=6
ordinal fi=clinical.dat
Labels age1 age2 sex1 sex2 type dummy
Definition_variables age1 age2 sex1 sex2 type /
Matrices 
A Full 2 2 =%E2 ! corr between A factors 
B Full 2 2 =%E4 ! corr between B factors 
P Full 1 1 =P5 ! probability of being comorbid given A 
R Full 1 1 =R5 ! probability of being comorbid given B 
O Full 1 2 ! matrix for age definition variable
M Full 1 2 ! matrix for sex definition variable
T Full 1 2 =T5! Estimated Threshold for A 
Q Full 1 2 =Q5! age difference in threshold for A
X Full 1 2 =X5! sex difference in threshold for A
U Full 1 2 =U5! Estimated Threshold for B 
S Full 1 2 =S5! age difference in threshold for B
Y Full 1 2 =Y5! sex difference in threshold for B
V Full 1 1 ! variance of dummy variable
L Full 4 1 ! for extracting right part of K
W Full 1 1 ! 0 + + These are to control integral type  
Z Full 1 1 ! 1 - - ! also ascertainment parameter for illicit drug dependence (fixed to 1)
n full 1 1 free ! ascertainment parameter for alcohol dependence
Begin Algebra; 
C = \muln((A_(T+(O.Q)+(M.X))_(T+(O.Q)+(M.X))_Z|Z)) ;    ! lower/lower A
D = \muln((A_(T+(O.Q)+(M.X))_(T+(O.Q)+(M.X))_Z|W)) ;    ! lower/upper A
E = \muln((A_(T+(O.Q)+(M.X))_(T+(O.Q)+(M.X))_W|Z)) ;    ! upper/lower A
F = \muln((A_(T+(O.Q)+(M.X))_(T+(O.Q)+(M.X))_W|W)) ;    ! upper/upper A
G = \muln((B_(U+(O.S)+(M.Y))_(U+(O.S)+(M.Y))_Z|Z)) ;    ! lower/lower B
H = \muln((B_(U+(O.S)+(M.Y))_(U+(O.S)+(M.Y))_Z|W)) ;    ! lower/upper B
I = \muln((B_(U+(O.S)+(M.Y))_(U+(O.S)+(M.Y))_W|Z)) ;    ! upper/lower B
J = \muln((B_(U+(O.S)+(M.Y))_(U+(O.S)+(M.Y))_W|W)) ;    ! upper/upper B
K =	 
    (z).(C.I.(Z-R))_												! 2 (expected probability of 0100)
    (n).(E.G.(Z-P))_												! 4 (expected probability of 1000)
    (z+n).(E.I + E.G.P + C.I.R)_										! 6 (expected probability of 1100)
    (z).(C.J.(Z-R).(Z-R))_											! 8 (expected probability of 0101)
    (n).(E.H.(Z-P).(Z-R))_											! 9 (expected probability of 1001)
    (z).(D.I.(Z-P).(Z-R))_											! 10 (expected probability of 0110)
    (z+n).(E.J.(Z-R) + E.H.P.(Z-R) + C.J.R.(Z-R))_							! 11 (expected probability of 1101)
    (z).(D.J.(Z-R) + D.I.P.(Z-R) + C.J.R.(Z-R))_							! 12 (expected probability of 0111)
    (n).(F.G.(Z-P).(Z-P))_											! 13 (expected probability of 1010)
    (z+n).(F.I.(Z-P) + F.G.P.(Z-P) + D.I.R.(Z-P))_							! 14 (expected probability of 1110)
    (n).(F.H.(Z-P) + F.G.P.(Z-P) + E.H.R.(Z-P))_							! 15 (expected probability of 1011)
    (z+n).(F.J + F.H.P + F.I.P + F.G.P.P + D.J.R + D.I.P.R + E.J.R + E.H.P.R + C.J.R.R);  ! 16 (expected probability of 1111)
End algebra; 
Matrix L 1 1 1 1
Matrix V .159154943
Matrix P .5
Matrix R .5
Matrix W 0
Matrix Z 1
Matrix N .5
Specify O age1 age2;
Specify M sex1 sex2;
Specify L -5 0 -5 0;
Means W;
Covariance V;
Weight (\part((K%( \sum(K)_\sum(K)_\sum(K)_\sum(K)_\sum(K)_\sum(K)_\sum(K)_\sum(K)_\sum(K)_\sum(K)_\sum(K)_\sum(K))),L)) /
Option func=1.e-7 nd=7 !diff=.001 
Option RS mu CI 90 
Option Th=-3
End