G1 CALCULATION GROUP Control group Correlation matrix A factor 
DA CALC NG=4 
MATRICES 
A Lo 2 2 Fixed 
C Lo 2 2 Free 
E St 2 2 Free 
P Full 4 4
I Iden 4 4
H Fu 1 1 
begin algebra; 
X = A*A' ; 
Y = C*C' ; 
Z = E ; 
end algebra; 
COMPUTE \stnd ((I-P)~ *( X+Y+Z| H@X+Y _ 
               H@X+Y| X+Y+Z)*((I-P)~)') / 
Specify P
0 0 0 0
5 0 0 0
0 0 0 0
0 0 5 0
Matrix H .5 
Matrix A 0 0 0
Bo 0 1 5 
Option RS SE 
End 

G2 CALCULATION GROUP Clinical group Correlation matrix A factor 
DA CALC 
MATRICES 
A Lo 2 2 = A1 
C Lo 2 2 = C1 
E St 2 2 = E1 
P Full 4 4 = P1
I Iden 4 4 = I1
H Fu 1 1 ! .5 
begin algebra; 
X = A*A' ; 
Y = C*C' ; 
Z = E ; 
end algebra; 
COMPUTE \stnd ((I-P)~ *( X+Y+Z| H@X+Y _ 
               H@X+Y| X+Y+Z)*((I-P)~)') / 
Matrix H .5 
Option RS SE 
End 

Correlated liability model: control group data 
Data Ni=1 No=1 
matrices 
i iden 1 1 
o full 10 1 
n full 1 1 ! scalar 2.0 
r full 4 4 =%e1 ! correlation matrix A1B1A2B2 
t full 1 4   ! thresholds abab 
y full 1 1 ! sample size 
z zero 1 1 
begin algebra ; 
K =  \muln(r_t_t_(i|i|i|i)) _ 
    n. \muln(r_t_t_(i|i|i|z)) _ 
    n. \muln(r_t_t_(i|i|z|i)) _ 
    n. \muln(r_t_t_(i|i|z|z)) _ 
       \muln(r_t_t_(i|z|i|z)) _ 
    n. \muln(r_t_t_(i|z|z|i)) _ 
    n. \muln(r_t_t_(i|z|z|z)) _ 
       \muln(r_t_t_(z|i|z|i)) _ 
    n. \muln(r_t_t_(z|i|z|z)) _ 
       \muln(r_t_t_(z|z|z|z))  ; 
M = \sum(K);
U = M_M_M_M_M_M_M_M_M_M; 
L = Y@(K%U) ; 
end algebra ; 
compute \sum((L-O).(L-O)%L) ; 
specify t 6 7 6 7
matrix n 2 
matrix o 244 21 21 15 2 3 1 0 3 3
matrix t 1 1 1 1
matrix y 313
bound 0 3 6 7
!fix all 
option user func=1.e-6 rs mu nd=8 
end 

Correlated liability model: inefficient approach; clinical group data 
Data Ni=1 No=1 
matrices 
i iden 1 1 
n full 1 1 ! scalar 2.0 
o full 9 1 
r full 4 4 =%E2 ! correlation matrix A1B1A2B2 
t full 1 4 = t3! thresholds abab 
y full 1 1 ! sample size 
z zero 1 1 
b full 1 1 
c full 1 1 free
begin algebra ; 
G = B+C;
K = 
    b.   \muln(r_t_t_(i|z|i|i)) _ 
    c.   \muln(r_t_t_(z|i|i|i)) _ 
    g.   \muln(r_t_t_(z|z|i|i)) _ 
    b.   \muln(r_t_t_(i|z|i|z)) _ 
    (b+c).   \muln(r_t_t_(i|z|z|i)) _ 
    (b+g).   \muln(r_t_t_(z|z|i|z)) _ 
    c.   \muln(r_t_t_(z|i|z|i)) _ 
    (c+g).   \muln(r_t_t_(z|i|z|z)) _ 
    g.   \muln(r_t_t_(z|z|z|z))  ; 
M = \sum(K);
U = M_M_M_M_M_M_M_M_M; 
L = Y@(K%U) ; 
end algebra ; 
compute \sum((L-O).(L-O)%L) ; 

Start .4 all
matrix b 1 
!matrix c 1
matrix o 67 17 79 5 5 20 3 6 10
matrix y 212
bound 0 100 8
option user rs 
option Th=-30
end 

save corrace.mxs
! no correlation model
drop 2 4
end