!Twin analysis using selected and unselected twin pairs
!Datafiles: controlmz.dat controldz.dat selectedmz.dat selectedz.dat
!Analysis of reading ability measure
!Selected Samples: at least 1 cotwin scores below criterion (-2Z)
!When both cotwins score below criterion pair is double-entered?

#define nvar 1              ! univariate analysis
#define nsib 2              ! number of siblings
#NGroups 5

G1: Parameter Estimates
 Calculation
 Begin Matrices;
  X Lower nvar nvar Free    !additive genetic effects
  W Lower nvar nvar Free    !shared environment effects
  Z Lower nvar nvar Free    !unique environment effects
  U Full 1 1 Free           !unselected cotwin means (equated)
  H Full 1 1
 End Matrices;
  Matrix H .5
 Begin Algebra;
  A= X*X';                  !additive genetic variance
  C= W*W';                  !shared environmental variance
  E= Z*Z';                  !unique environmental variance
  B= A+C;                   !control MZ sibling covariance
  G= H@A + C;               !control DZ sibling covariance
  V= A+C+E;                 !total variance
  T= A|C|E;                 !parameters in one matrix for standardizing
  S= T@V~;                  !standardized variance component estimates
 End Algebra;
  Labels Row S standest
  Labels Col S a^2 c^2 e^2
  Labels Row T unstandest
  Labels Col T a^2 c^2 e^2
End

G2: Control Monozygotic twins
 Data NInput=4 
 Rectangular File=controlmz.dat
 Labels famid zygosity phen1 phen2
 Select phen1 phen2 /
 Matrices = Group 1;
 Means U | U;
 Covariance  V | B_
             B | V;
Options ND=3 RS
End

G3: Control Dizygotic twins
 Data NInput=4 
 Rectangular File=controldz.dat
 Labels famid zygosity phen1 phen2
 Select phen1 phen2 /
 Matrices = Group 1;
 Means U | U;
 Covariance  V | G_
             G | V;
Options ND=3 RS
End

G4: Selected Monozygotic twins
 Data NInput=7 
 Rectangular File=selectedmz.dat
 Labels famid zygosity pibd0 pibd1 pibd2 phen1 phen2
 Select phen1 phen2 /
 Matrices = Group 1;
 D Full nvar nvar free      !selected proband variance
 J Full nvar nvar free      !selected proband mean
Begin Algebra;
 N=U+((J-U)*V~*B);          !expected selected MZ cotwin mean
 M=J|N;                     !selected pair means (proband,cotwin)
End Algebra;
!
MEANS M;                    !adjusted means for selected twins
CO D       | D*V~*B_
   B'*V~*D | V-B'*(V~-V~*D*V~)*B;    !cov matrix for selected MZ twins
Options ND=3 RS
End

G5: Selected Dizygotic twins
 Data NInput=7 
 Rectangular File=selecteddz.dat
 Labels famid zygosity pibd0 pibd1 pibd2 phen1 phen2
 Select phen1 phen2 /
 Matrices = Group 1;
 D Full nvar nvar =D4       !selected proband variance
 J Full nvar nvar =J4       !selected proband mean
Begin Algebra;
 N=U+((J-U)*V~*G);          !expected selected DZ cotwin mean
 M=J|N;                     !selected pair means (proband,cotwin)
End Algebra;
!
MEANS M;                    !adjusted means for selected twins
CO D       | D*V~*G_
   G'*V~*D | V-G'*(V~-V~*D*V~)*G;    !cov matrix for selected MZ twins
!
 Start .42 All 
 Start 0 U(1,1,1)
 Start 0.40 D(4,1,1)
 Start -2.00 J(4,1,1)
Options ND=3 RS
End