! Correlations for this CpG site

! Methylation variation at IGF2 locus
! Adolescent twins (Dorret)

G1: calculation group
 Data Calc NGroups=3
  Begin matrices;
    X dia 2 2 Free			!  (standard deviation) MZ
    Y stand 2 2 Free		!  correlation MZ
    S dia 2 2 Free			!  (standard deviation) DZ
    T stand 2 2 Free		!  correlation DZ

     G Full 1 1  free		! grand mean phenotypes
     P full  2 1 free 		! estimated regression effects of the covariates
  End matrices;

EQ S 1 1 S 2 2
EQ X 1 1 X 2 2

 st 0.8 X 1 1 1 X 1 2 2  S 1 1 1  S 1 2 2		! provide starting values
 st .4 Y 1 2 1 T 1 2 1
 st 3.0 G 1 1 1 
 st -0.01 P 1 1 1 P 1 2 1
End

G2: MZ twins, datagroup
 Data NInput_vars= 9			! nr of inputvars per family
 Missing=-9.00			! missing values = -9.00
 REctangular file=mx_igf2_aug08_mp2.dat	! read in raw datafile, must be in same directory

 LABELS  family zyg age sex sex_2 IGF2_RS1004446.1 IGF2_RS1004446.2  mp2 mp2_2	! tell Mx what is found in the datafile
  
 Select if  zyg = 1 ; 			! Select MZs
Select age sex sex_2 mp2 mp2_2 ;		! def vars and CpG site analysed = Promoter CpG2
definition age sex sex_2 ;

Matrices = group 1 
    V Full   1 2 fix			! observed covariates for twin 1
    W Full 1 2 fix			! observed covariates for twin 2
 end matrices;

Specify V age sex;
Specify W age sex_2 ;

     Means G+V*P | G+W*P ;		! means model 
     Covariances X*Y*X' ;		! model for MZ variance/covariances
End

G3: DZ twins, datagroup
 Data NInput_vars= 9			! nr of inputvars per family
 Missing=-9.00			! missing values 
  REctangular file=mx_igf2_aug08_mp2.dat	! read in raw datafile, must be in same directory

 LABELS  family zyg age sex sex_2 IGF2_RS1004446.1 IGF2_RS1004446.2  mp2 mp2_2
  
Select if  zyg = 2 ; 
Select age sex sex_2 mp2 mp2_2 ;		! def vars and CpG site analysed = Promoter CpG2
definition age sex sex_2 ;

Matrices = group 1 
    V Full 1 2 fix			! observed covariates for twin 1
    W Full 1 2 fix			! observed covariates for twin 2
 end matrices;

Specify V age sex;
Specify W age sex_2 ;

     Means G+V*P | G+W*P ;		! means model 
     Covariances  S*T*S';			! model for DZ variance/covariances
End