! Correlations for this CpG site

! Methylation variation at IGF2 locus
! Adolescent twins (Dorret)

G1: calculation group
 Data Calc NGroups=3
  Begin matrices;
    X dia 2 2 Free			!  (standard deviation) MZ
    Y stand 2 2 Free		!  correlation MZ
    S dia 2 2 Free			!  (standard deviation) DZ
    T stand 2 2 Free		!  correlation DZ
     G Full 1 1  free		! grand mean phenotypes MZ
     H Full 1 1 free			 ! grand mean phenotypes DZ
  End matrices;

eq X 1 1 X 2 2 S 1 1 S 2 2	!equal SD
eq G 1 1 H 1 1			!equal means

 st 1.0 X 1 1 1 X 1 2 2		! provide starting values
 st .4 Y 1 2 1 T 1 2 1
 st 1.0 S 1 1 1  S 1 2 2
 st 3.0 G 1 1 1 H 1 1 1 
end

G2: MZ twins, datagroup
 Data NInput_vars= 9			! nr of inputvars per family
 Missing=-9.00			! missing values = -9.00
 REctangular file=mx_igf2_aug08_mp2.dat	! read in raw datafile, must be in same directory

 LABELS  family zyg age sex sex_4 IGF2_RS1004446.1 IGF2_RS1004446.2  mp2 mp2_2	! tell Mx what is found in the datafile
  
 Select if  zyg = 1 ; 		! Select MZs
Select mp2 mp2_2 ;		! CpG site analysed = Promoter CpG2

Matrices = group 1 
 end matrices;

     Means G | G;			! model for means, assuming grand mean twin 1 = grand mean twin 2
     Covariances X*Y*X' ;		! model for MZ variance/covariances
	
Options RSiduals
End

G3: DZ twins, datagroup
 Data NInput_vars= 9			! nr of inputvars per family
 Missing=-9.00			! missing values 
  REctangular file=mx_igf2_aug08_mp2.dat	! read in raw datafile, must be in same directory

 LABELS  family zyg age sex sex_4 IGF2_RS1004446.1 IGF2_RS1004446.2  mp2 mp2_2
  
Select if  zyg = 2 ; 
select mp2 mp2_2;	! CpG site analysed = Promoter CpG2

  Matrices = group 1 
  End matrices;
     Means H | H;		! model for means, assuming grand mean twin 1 = grand mean twin 2
     Covariances  S*T*S';	! model for DZ variance/covariances

 Options RSiduals
End