! Estimate Genetic and Environmental Components - ACED model
! Dutch Adult Twins: Lipid levels

#define nvar 1
#define nvar2 2
#NGroups 4

Title G1: Model Parameters
 Calculation
 Begin Matrices;
  X Lower nvar nvar Free    ! additive genetic path, a
  Y Lower nvar nvar Free    ! common environmental path, c
  Z Lower nvar nvar Free    ! specific environmental path, e
  W Lower nvar nvar         ! dominance genetic path, d
  H Full 1 1                ! scalar, 0.5
  Q Full 1 1                ! scalar, 0.25
 End Matrices;
  Label Row X add_gen
  Label Row Y comm_env
  Label Row Z spec_env
  Label Row W dom_gen
  Matrix H .5
  Matrix Q .25
 Begin Algebra;
  A= X*X';                  ! additive genetic variance, a^2
  C= Y*Y';                  ! common environmental variance, c^2
  E= Z*Z';                  ! specific environmental variance, e^2
  D= W*W';                  ! dominance genetic variance, d^2
 End Algebra;
End Group

Title G2: MZ data
#include DutchMZ.dat
  Select
   t1$var
   t2$var ;
 Begin Matrices = Group 1;
  M Full 1 nvar2 Free
 End Matrices;
  Matrix M 4 4
 Means M;
 Covariance 
    A+C+E+D | A+C+D   _  
    A+C+D   | A+C+E+D;
 Option RSiduals;
End

Title G3: DZ data
#include DutchDZ.dat
  Select
   t1$var
   t2$var ;
 Begin Matrices = Group 1;
  M Full 1 nvar2 Free
 End Matrices;
  Matrix M 4 4
 Means M;
 Covariance
    A+C+E+D   | H@A+C+Q@D _
    H@A+C+Q@D | A+C+E+D;
 Option RSiduals
End

Title G4: Standardization
 Calculation
 Begin Matrices = Group 1;
 End Matrices;
  Start .6 all
 Begin Algebra;
  V=A+C+E+D;                ! total variance
  P=A|C|E|D;                ! concatenate parameter estimates
  S=P@V~;                   ! standardized parameter estimates
 End Algebra;
  Label Col P a^2 c^2 e^2 d^2
  Label Col S a^2 c^2 e^2 d^2
!ACE model
! Interval S 1 1 - S 1 4
 Option NDecimals=4
 Option Multiple Issat
End

Save ACE.mxs
! Test significance of genetic factors
 Drop X 1 1 1
End

Get ACE.mxs
! Test significance of shared environmental factors
 Drop Y 1 1 1
Exit