! your task is to add three jobs to this script
! 1 test the significant of age moderation on A
! 2 test the significant of age moderation on E
! 3 test the significant of age moderation on both A and E jointly
! put up your hand if your having trouble
! good luck

! GxE - Basic model

G1: Define Matrices
Data Calc NGroups=3
Begin Matrices;
X full 1 1 free
W full 1 1 fixed
Z full 1 1 free
T full 1 1 free	 ! moderator-linked A component
U full 1 1 fixed      ! moderator-linked D component
V full 1 1 free	 ! moderator-linked E component
M full 1 1 free	 ! grand mean
B full 1 1 free  ! moderator-linked means model
H full 1 1
Q full 1 1
R full 1 1	! twin 1 moderator (definition variable)
S full 1 1	! twin 2 moderator (definition variable)
End Matrices;
Ma T 0
Ma U 0
Ma V 0
Ma M 21
Ma B 0
Ma X 1
Ma W 0
Ma Z 1
Label R T Age_A
Label R U Age_D
Label R V Age_E
Label R X A
Label R W D
Label R Z E
Matrix H .5
Matrix Q .25
Options NO_Output
End

G2: MZ
Data NInput=13
 Rectangular File=mod.rec
 Labels fam agecat zage zyg part wt1 wt2 ht1 ht2 htwt1 htwt2 bmi1 bmi2

Select if zyg = 2 /
Select bmi1 bmi2 zage /
Definition zage /
Matrices = Group 1
Means M + B*R |M + B*S / 
Covariance 	 
(X+T*R)*(X+T*R) + (W+U*R)*(W+U*R) + (Z+V*R)*(Z+V*R)  | (X+T*R)*(X+T*S) +  (W+U*R)*(W+U*S)  _
(X+T*S)*(X+T*R) + (W+U*S)*(W+U*R) | (X+T*S)*(X+T*S) + (W+U*S)*(W+U*S) + (Z+V*S)*(Z+V*S) /
!twin 1 moderator variable
Specify R zage 
!twin 2 moderator variable
Specify S zage
Options NO_Output
End
 
G3: DZ
Data NInput=13
 Rectangular File=mod.rec
 Labels fam agecat zage zyg part wt1 wt2 ht1 ht2 htwt1 htwt2 bmi1 bmi2

Select if zyg = 4 /
Select bmi1 bmi2 zage /
Definition zage /
Matrices = Group 1
Means M + B*R |M + B*S  / 
Covariance 	 
(X+T*R)*(X+T*R) + (W+U*R)*(W+U*R) + (Z+V*R)*(Z+V*R)  | H@(X+T*R)*(X+T*S) +  Q@(W+U*R)*(W+U*S)  _
H@(X+T*S)*(X+T*R) + Q@(W+U*S)*(W+U*R) | (X+T*S)*(X+T*S) + (W+U*S)*(W+U*S) + (Z+V*S)*(Z+V*S) /
!twin 1 moderator variable
Specify R zage
!twin 2 moderator variable
Specify S zage
option multiple issat
End