! Genetic Simplex (autoregressive) Model

!  Australian alcohol challenge data, assessed in 1979
!  bac=blood alcohol concentration
!  2nd, 3rd, 4th, and 6th assessments after challenge dose
!  Grant et al., 1999, Behavior Genetics


#define NVAR 4

G1: Genetic structure
Data Calc NGroups=3
Begin Matrices;
X Diag NVAR NVAR Free     ! genetic innovations
Y Diag NVAR NVAR Fixed    ! common environmental innovations
Z Diag NVAR NVAR Free     ! unique environmental innovations
U Diag NVAR NVAR Free     ! measurement error variances
N Lower NVAR NVAR Free    ! genetic transmissions 
O Lower NVAR NVAR Fixed   ! common environmental transmissions
P Lower NVAR NVAR Free    ! unique environmental transmissions
I Iden NVAR NVAR          ! identity matrix
H Full 1 1                ! genetic weight for DZs
M Full 1 8 Free           ! means
End Matrices;

Matrix H .5

Specify N
0
101 0
0 102 0
0 0 103 0


!  Specify O  !this would be if the model had common environmental transmissions
!  0
!  106 0
!  0 107 0
!  0 0 108 0

Specify P
0
111 0
0 112 0
0 0 113 0

Specify U
200 200 200 200				!note I've constrained these to be the same

Begin Algebra;
A = (I-N)~ & (X*X');			!variance components now a function of innovations and transmissions
C = (I-O)~ & (Y*Y');
E = (I-P)~ & (Z*Z') + U*U';
End Algebra;
End

G2: Male MZ twin pairs
Data NInput_vars=8 NObservations=43
Labels
bac2_a bac3_a bac4_a bac6_a bac2_b bac3_b bac4_b bac6_b

Rectangular File=bac_mzm4.dat

Matrices = Group 1;

Means M /

Covariances A+C+E | A+C _
                       A+C   | A+C+E /

Start 10 x 1 1 z 1 1 z 3 3 
Start 5  x 2 2 x 4 4 z 2 2 z 4 4
Start 1 x 3 3
Start 1  n 2 1 n 3 2 n 4 3 
Start 0.5 p 2 1 p 3 2 p 4 3
Start 80 m 1 1 m 1 2 m 1 3 m 1 4 m 1 5 m 1 6 m 1 7 m 1 8
Start 0.5 u 1 1 u 2 2 u 3 3 u 4 4 

BO 0.001 500 x(1,1) x(2,2) x(3,3) x(4,4)
BO 0.001 500 z(1,1) z(2,2) z(3,3) z(4,4)
BO 0.001 10  n(2,1) n(3,2) n(4,3)
BO 0.001 10  p(2,1) p(3,2) p(4,3)

!Interval x 1 1 x 2 2 x 3 3 x 4 4	!CIs around genetic innovations
!Interval z 1 1 z 2 2 z 3 3 z 4 4	!CIs around E innovations
!Interval n 2 1 n 3 2 n 4 3 			!CIs around genetic transmissions
!Interval p 2 1 p 3 2 p 4 3			!CIs around E transmissions
!Interval u 1 1 					!CIs around error variance

End 

G3: Male DZ twin pairs
Data NInput_vars=8 NObservations=37
Labels
bac2_a bac3_a bac4_a bac6_a bac2_b bac3_b bac4_b bac6_b

Rectangular File=bac_dzm4.dat

Matrices = Group 1;

Means M /

Covariances A+C+E | H@A+C _
                   H@A+C | A+C+E /

Option Multiple Issat
End