! Estimate genetic and environmental components - ACED model
! OZ BMI data - younger females

#NGroups 4
#define nvar 1
#define nvar2 2

Title 1: Model Parameters
 Calculation
 Begin Matrices;
  X Lower nvar nvar Free
  Y Lower nvar nvar 
  Z Lower nvar nvar Free
  W Lower nvar nvar Free
  H Full 1 1
  Q Full 1 1
 End Matrices;
  Matrix H .5
  Matrix Q .25
 Begin Algebra;
  A= X*X';
  C= Y*Y';
  E= Z*Z';
  D= W*W';
 End Algebra;
End Group

Title 2: MZ data
 #include ozbmi2.dat
 Select if zyg=1
 Select if agecat=1
 Select bmi1 bmi2 ;
 Begin Matrices = Group 1;
  M Full 1 nvar2 Free
 Means M;
 Covariance 
    A+C+E+D | A+C+D   _  
    A+C+D   | A+C+E+D;
 Option RSiduals;
End

Title 3: DZ data
 #include ozbmi2.dat
 Select if zyg=3
 Select if agecat=1
 Select bmi1 bmi2 ;
 Begin Matrices = Group 1;
  M Full 1 nvar2 Free
 End Matrices;
 Means M;
 Covariance
    A+C+E+D   | H@A+C+Q@D _
    H@A+C+Q@D | A+C+E+D;
 Option RSiduals
End

Title 4: Standardization
 Calculation
 Begin Matrices = Group 1;
 End Matrices;
  Start .5 all
  Start 20 M 2 1 1 - M 2 1 nvar2
  Start 20 M 3 1 1 - M 3 1 nvar2
 Begin Algebra;
  V=A+C+E+D;
  P=A|C|E|D;
  S=P@V~;
 End Algebra;
 Interval S 1 1 - S 1 4
 Option NDecimals=4
!ADE model
 Option Sat=4055.935,1767
 Option Multiple
End

!AE model
 Drop W 1 1 1
End

!ACE model
 Free Y 1 1 1
End

!CE model
 Drop X 1 1 1
End

!E model
 Drop Y 1 1 1
End