! Estimate means and variances - Saturated model
! OZ BMI data

#NGroups 2                   ! number of groups for this analysis
#define nvar2 2              ! number of variables in this analysis, bmi1 bmi2

Title 1: MZ data
 #include ozbmi2.dat
! the following lines from an external file are included at this stage
! Data NInput=13
! Rectangular File=ozbmi2.rec
! Labels fam agecat age zyg part wt1 wt2 ht1 ht2 htwt1 htwt2 bmi1 bmi2
 Select if zyg =1            ! select MZ's
 Select if agecat =1         ! select young cohort
 Select bmi1 bmi2 ;          ! select variables for analysis
 Begin Matrices;
  M Full 1 nvar2 Free        ! free parameters for 2 means
  X Symm nvar2 nvar2 Free    ! free parameters for 2 variances and covariance
 End Matrices;
  Start 20 M 1 1 - M 1 nvar2 ! starting values for means
  Start 1 X 1 1 X 2 2        ! starting values for variances
 Means M;                    ! expected mean vector
 Covariance X;               ! expected covariance matrix
 Options RSiduals            ! print observed and expected means, covariance matrix
End

Title 2: DZ data
 #include ozbmi2.dat
 Select if zyg =3
 Select if agecat =1
 Select bmi1 bmi2 ;
 Begin Matrices;
  M Full 1 nvar2 Free
  X Symm nvar2 nvar2 Free 
 End Matrices;
  Start 20 M 1 1 - M 1 nvar2
  Start 1 X 1 1 X 2 2
 Means M;
 Covariance X;
 Options RSiduals
End