! SCRIPT NAME: saturated model AQ and cbcl syndrome scores
! GOAL: To regress cbcl scores on AQ scores, also taking sex & Age effect into account

! DATA: continuous
! INPUT: raw data
! DATA-GROUPS: MZ DZ  (in alle groepen zitten ook Sibs)
! data within families: twin 1 twin 2 sib

! MEANS MODEL	: 1 grand mean, taking into account effect of CBCL scales age and sex 
! VARIANCE COVARIANCE MODEL:  MZ & DZ covariance

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
#define nvar 1			! number of dependent variables per individual
#define ndef 10			! number of covariates per individual (8 cbcl syndrome scales + sex and age in this script)

G1: calculation group 
 Data Calc NGroups=3

  Begin matrices;
	J full 1 nvar free  		! grand mean
	P full ndef nvar Free		! estimated effects of the covariates

	A sym nvar nvar free   	! twin var AND sib var
	
	G sym nvar nvar free  	! cov MZt1-t2
	H sym nvar nvar free   	! cov DZt1-t2
	I sym nvar nvar free    	! cov MZtwin-sib en DZtwin-sib
		
  End matrices;

 !provide starting values
 st 102 J 1 1  				! starting values mean AQ 
 st 90 A 1 1				! var
 st 30 G 1 1				! covar
 st 25 H 1 1 				! covar
 st 20 I 1 1					! covar

st -.4 P 1 1 
st -.4 P 2 1 
st 1.6 P 3 1 
st 0.1 P 4 1 
st 0.01 P 5 1 
st 1.2 P 6 1 
st 0.7 P 7 1 
st 0.1 P 8 1 
st -.6 P 9 1
st 0.1 P 10 1	 	! starting values voor definition variables (agesex cbcl scales; )
 
 Begin Algebra;
	T = \stnd(A|G|I_G|A|I_I|I|A) ;		!off-diagonal is MZ correlation
	U = \stnd(A|H|I_H|A|I_I|I|A) ;		!off-diagonal is DZ correlation
  End Algebra ;

Labels row P age sekse withdr somatic anxiety social thought attention rulebreak aggress;

!Drop @0 P 1 1 1						! no age effect
option no_output
end

G2: MZ twins					! MZM
	Data Ninput_vars=36		 		! Number of variables per family
	missing=-1.00				! Missing values voor afhankelijke variabelen
						!NB: missing values dependent vars moeten andere waarden hebben (hier -4.00)
	Rectangular file=Comb_AQ_YSR.dat		! read raw data, this is the file created in SPSS
	Labels					! provide labels for the variables
	ntrid zyg5gr zygMZDZ age1 sekse1  wit1 som1 anx1 soc1 tho1 att1 del1 agg1 AQ1
                           age2 sekse2  wit2 som2 anx2 soc2 tho2 att2 del2 agg2 AQ2
                           age3 sekse3  wit3 som3 anx3 soc3 tho3 at3 del3 agg3 AQ3
	
	select if zygMZDZ = 1				! select if zygosity is MZ
	select age1 sekse1  wit1 som1 anx1 soc1 tho1 att1 del1 agg1 AQ1 
             age2 sekse2  wit2 som2 anx2 soc2 tho2 att2 del2 agg2 AQ2
             age3 sekse3  wit3 som3 anx3 soc3 tho3 at3 del3 agg3 AQ3;
	Definition age1 sekse1  wit1 som1 anx1 soc1 tho1 att1 del1 agg1
                 age2 sekse2  wit2 som2 anx2 soc2 tho2 att2 del2 agg2
                 age3 sekse3  wit3 som3 anx3 soc3 tho3 at3 del3 agg3;

Matrices = Group 1			! get all matrices from group 1

    V Full 1 ndef fix			! observed covariates for twin 1
    W Full 1 ndef fix			! observed covariates for twin 2
    X Full 1 ndef fix			! observed covariates for sib

End matrices;

Specify V age1 sekse1 wit1 som1 anx1 soc1 tho1 att1 del1 agg1 
Specify W age2 sekse2 wit2 som2 anx2 soc2 tho2 att2 del2 agg2 
Specify X age3 sekse3 wit3 som3 anx3 soc3 tho3 at3 del3 agg3;  

     Means J+V*P | J+W*P | J+X*P;		! means model 

     Covariances				! variance/covariance model
	A | G | I _
	G | A | I_
	I | I | A ;
end

G3: DZ twins					! DZ twins plus 1 sib
	Data Ninput_vars=36		 		! Number of variables per family
	missing=-1.00				! Missing values voor afhankelijke variabelen
						!NB: missing values dependent vars moeten andere waarden hebben (hier -4.00)
	Rectangular file=Comb_AQ_YSR.dat		! read raw data, this is the file created in SPSS
	Labels					! provide labels for the variables
	ntrid zyg5gr zygMZDZ age1 sekse1  wit1 som1 anx1 soc1 tho1 att1 del1 agg1 AQ1
                            age2 sekse2  wit2 som2 anx2 soc2 tho2 att2 del2 agg2 AQ2
                            age3 sekse3  wit3 som3 anx3 soc3 tho3 at3 del3 agg3 AQ3
	
	select if zygMZDZ = 2					! select if zygosity is DZ
	select age1 sekse1  wit1 som1 anx1 soc1 tho1 att1 del1 agg1 AQ1 
                  age2 sekse2  wit2 som2 anx2 soc2 tho2 att2 del2 agg2 AQ2
                  age3 sekse3  wit3 som3 anx3 soc3 tho3 at3 del3 agg3 AQ3;
	Definition age1 sekse1  wit1 som1 anx1 soc1 tho1 att1 del1 agg1
                       age2 sekse2  wit2 som2 anx2 soc2 tho2 att2 del2 agg2
                       age3 sekse3  wit3 som3 anx3 soc3 tho3 at3 del3 agg3;

Matrices = Group 1			! get all matrices from group 1

    V Full 1 ndef fix			! observed covariates for twin 1
    W Full 1 ndef fix			! observed covariates for twin 2
    X Full 1 ndef fix			! observed covariates for sib

End matrices;

Specify V age1 sekse1 wit1 som1 anx1 soc1 tho1 att1 del1 agg1 
Specify W age2 sekse2 wit2 som2 anx2 soc2 tho2 att2 del2 agg2 
Specify X age3 sekse3 wit3 som3 anx3 soc3 tho3 at3 del3 agg3;

     Means J+V*P | J+W*P | J+X*P;		! means model 
     Covariances				! variance/covariance model
	A| H | I _
	H | A | I_
	I | I | A ;

Option mul issat
option it=2000
end

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!EINDESCRIPT!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!NB age(1) sekse(2) withdr(3) somatic(4) anxiety(5) social(6) thought(7) attention(8) rulebreak(9) aggress(10)

save satysr.mxs				! save
get satysr.mxs

Drop@0 P 1 8 1				! 1b.Test significance attention problems
end

!get satysr.mxs

Drop @0 P 1 5 1				! 1c.Test significance 
end

!get satysr.mxs

Drop@0 P 1 10 1				!  1d.Test significance 
end

!get satysr.mxs

Drop @0 P 1 4 1				! 1e.Test significance
end

!get satysr.mxs

Drop @0 P 1 9 1				! 1f Test significance
end

!get satysr.mxs

Drop@0 P 1 7 1				! 1g Test significance 
end

!get satysr.mxs

Drop @0 P 1 6 1				! 1h Test significance
end

!get satysr.mxs

Drop@0 P 1 3 1				! 1i Test significance 
end

Drop@0 P 1 2 1				! drop sex effect
end