! Estimate Genetic (QTL) and Environmental Components - FEQ model
! Dutch Adult Twins: Lipid levels (position 65 cM chromosome 19)
#define $var ldl  
!3 variables in the file ldl apob apoe
#define nvar 1
#define nvarx2 2
#NGroups 5

G1: Model Parameters
Calculation
 Begin Matrices;
  X Lower nvar nvar Free    ! residual familial path coefficients
  Z Lower nvar nvar Free    ! nonshared environment path coefficients
  T Lower nvar nvar Free    ! QTL path coefficients
  H Full 1 1
 End Matrices;
  Matrix H .5
  Start .3 All
 Begin Algebra;
  F=X*X';                   ! residual familial variance components
  E=Z*Z';                   ! nonshared environment variance components
  Q=T*T';                   ! QTL variance components
 End Algebra;
 Option Rsiduals
End

G2: DZ IBD2 twins
 Data NInput=18
  Rectangular File=DutchDZ.rec
  Labels zyg  sex1 age1 med1 t1ldl t1apob t1lnapoe  sex2 age2 med2 t2ldl t2apob t2lnapoe
   ibd0_65 ibd1_65 ibd2_65 pihat65 pi65cat
  Select if pi65cat =2;
  Select
   t1$var
   t2$var ;
 Begin Matrices = Group 1;
  M Full nvar nvarx2 Free
  K Full 1 1                ! correlation of QTL effects
 End Matrices;
  Matrix M 4 4
  Matrix K 1
 Means M;
 Covariance
    F+Q+E | F+K@Q _
    F+K@Q | F+Q+E;
End

G3: DZ IBD1 twins
 Data NInput=18
  Rectangular File=DutchDZ.rec
  Labels zyg  sex1 age1 med1 t1ldl t1apob t1lnapoe  sex2 age2 med2 t2ldl t2apob t2lnapoe
   ibd0_65 ibd1_65 ibd2_65 pihat65 pi65cat
  Select if pi65cat =1;
  Select
   t1$var
   t2$var ;
 Begin Matrices = Group 1;
  M Full nvar nvarx2 Free
  K Full 1 1
 End Matrices;
  Matrix M 4 4
  Matrix K .5
 Means M;
 Covariance
    F+Q+E | F+K@Q _
    F+K@Q | F+Q+E;
End

G4: DZ IBD0 twins
 Data NInput=18
  Rectangular File=DutchDZ.rec
  Labels zyg  sex1 age1 med1 t1ldl t1apob t1lnapoe  sex2 age2 med2 t2ldl t2apob t2lnapoe
   ibd0_65 ibd1_65 ibd2_65 pihat65 pi65cat
  Select if pi65cat =0;
  Select
   t1$var
   t2$var ;
 Begin Matrices = Group 1;
  M Full nvar nvarx2 Free
 End Matrices;
  Matrix M 4 4
 Means M;
 Covariance
    F+Q+E | F_
    F     | F+Q+E;
 Option Rsiduals Iterations=5000 NDecimals=4
 Option Multiple Issat
End

G5: Standardization
 Calculation
 Begin Matrices = Group 1;
 Begin Algebra;
  V=F+E+Q;                  ! total variance
  P=F|E|Q;                  ! concatenate parameter estimates
  S=P@V~;                   ! standardized parameter estimates
 End Algebra;
  Label Col P f^2 e^2 q^2
  Label Col S f^2 e^2 q^2
!FEQ model
 Interval S 1 1 - S 1 3
 Option Rsiduals Iterations=5000 NDecimals=4
 Option Multiple Issat
End

! Test for QTL
Drop T 1 1 1
Exit