!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!Boulder, March 2008
!ADE with Twins+Parents
!Type A Behavior
!I.Rebollo
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!


#define nvar 1						! number dependent variables per 
individual
#Define nvarnsib 4					! number of variables times the number of 
family member =  1 variable X 4 family members (tw1, tw2, father & mother)				

G1: calculation group 
 Data Calc NGroups=9

  Begin matrices;
	X Lower nvar nvar free			! Additive Genetic structure males
	W Lower nvar nvar free			! Dominance genetic structure males
	Z Lower nvar nvar free			! Unique environment males
	J Lower nvar nvar free			! Additive Genetic structure females
	Y Lower nvar nvar free			! Dominance genetic structure females
	L Lower nvar nvar free			! Unique environment females
	H Full 1 1	fix				! .5 for dz cov A
	Q Full 1 1	fix				! .25 for dz cov D
	F Zero  nvar nvar 				! Spouse correlations constrained to zero
	S full 1 1 free				! Scalar for parental generation
	N UNIT 2 2				! to be used in the scalar matrix
  End matrices;

 Matrix H .5					! Matrix H is fixed and contains .5
 Matrix Q .25					! Matrix Q is fixed and contains .2

  Begin algebra;
     A= X*X' ;			  		! additive genetic variance males
     D= W*W' ;   					! dominance genetic variance males
     E= Z*Z' ;					! unique environmental variance males
     T=J*J' ;						! additive genetic variance females
     U=Y*Y' ;					! dominance genetic variance females
     V= L*L' ;					! unique environmental variance females		
     B=  N     | (N@S)_
        (N@S)  | (N@(S*S'));				! matrix of scalars 	
	

  End algebra;
 
 st 2.6 X 1 1 1 
 st 2.6 J 1 1 1
 st 2.6 Z 1 1 1
 st 2.6 L 1 1 1
 st 1.7 W 1 1 1
 st 1.7 Y 1 1 1
 st 1 s 1 1
 
Options no_output

end

G2: MZM twins, datagroup
 Data  NInput_vars= 13			
 Missing=-1.00				
 REctangular file=typeamx.dat		
 LABELS     
 zygos jas1 jas2 jasf jasm sex1 sex2 sexf sexm age1 age2 agef agem  			
 Select if  zygos = 1 ; 		! select mzm		
 Select   jas1 jas2 jasf jasm  ;

 Matrices = group 1 
	G Full 1 nvarnsib free				! grand mean phenotypes
 end matrices;

 Specify G
 20 20 40 40 		!Same mean for 1st born and 2nd born, and same for mother and father

 Begin Algebra;
 	R = A+D+E   | A+D     | H@A   | H@(X*J') _
 	    A+D     | A+D+E   | H@A   | H@(X*J') _
	    H@A     | H@A     | A+D+E | F        _
	    H@(J*X')| H@(J*X')| F     | T+U+V    ;
 End Algebra;

 Means G  ;					! model for means
 Covariances					! model for MZM-PARENTS 
variance/covariances ADEi model
	B.R ;

st 10 G  1 1 - G  1 nvarnsib
End

G3: DZM twins, datagroup
 Data  NInput_vars= 13			
 Missing=-1.00					
 REctangular file=TYPEAMX.dat	
 LABELS     
 zygos jas1 jas2 jasf jasm sex1 sex2 sexf sexm age1 age2 agef agem  		
 Select if  zygos = 2 ; 		! select dzm		
 Select   jas1 jas2 jasf jasm    ;

  Matrices = group 1 
	G Full 1 nvarnsib free				! grand mean phenotypes		
  End matrices;

 Specify G
 20 20 40 40 				

 Begin Algebra;
 	R = A+D+E   | H@A+Q@D | H@A   | H@(X*J') _
 	    H@A+Q@D | A+D+E   | H@A   | H@(X*J') _
 	    H@A     | H@A     | A+D+E | F	      _
 	    H@(J*X')| H@(J*X')| F     | T+U+V    ;					
 End Algebra;

    Means G  ;			

    Covariances						!ADE
	B.R  ;

st 18 G  1 1 - G  1 nvarnsib
End

G4: MZF twins, datagroup
 Data NInput_vars= 13				
 Missing=-1.00					
 REctangular file=TYPEAMX.dat		
 LABELS     
 zygos jas1 jas2 jasf jasm sex1 sex2 sexf sexm age1 age2 agef agem  		
 Select if  zygos = 3 ; 		! select mzf	
 Select   jas1 jas2 jasf jasm  ;

 Matrices = group 1 
	G Full 1 nvarnsib free				! grand mean phenotypes
 End matrices;
 
 Specify G
 20 20 40 40

 Begin Algebra;
	 R = T+U+V   | T+U     | H@(J*X')| H@T _
	     T+U     | T+U+V   | H@(J*X')| H@T _
	     H@(X*J')| H@(X*J')| A+D+E   | F   _
	     H@T     | H@T     | F       | T+U+V    ;
End Algebra;

   Means G ;			
   Covariances					! ADE
	 B.R	;

st 10 G 1 1 - G  1 nvarnsib
End

G5: DZF twins, datagroup
 Data  NInput_vars= 13				
 Missing=-1.00					
 REctangular file=TYPEAMX.dat		
 LABELS     
 zygos jas1 jas2 jasf jasm sex1 sex2 sexf sexm age1 age2 agef agem  	
 Select if  zygos = 4 ; 		! select dzf	
 Select   jas1 jas2 jasf jasm   ;	

  Matrices = group 1 
      G Full 1 nvarnsib free				! grand mean phenotypes
  End matrices;

Specify G
20 20 40 40 

 Begin Algebra;
 R = T+U+V   | H@T+Q@U | H@(J*X')| H@T _
     H@T+Q@U | T+U+V   | H@(J*X')| H@T _
     H@(X*J')| H@(X*J')| A+D+E   | F   _
     H@T     | H@T     | F       | T+U+V    ;
End Algebra;

   Means G  ;			
   Covariances					! ADE
	 B.R	;

st 10 G  1 1 - G  1 nvarnsib
End

G6: OSMF twins, datagroup
  Data  NInput_vars= 13				
  Missing=-1.00					
  REctangular file=TYPEAMX.dat
  LABELS     
  zygos jas1 jas2 jasf jasm sex1 sex2 sexf sexm age1 age2 agef agem  
  Select if  zygos = 5 ; 		! select dosmf		
  Select   jas1 jas2 jasf jasm   ;
 
  Matrices = group 1 
      G Full 1 nvarnsib free				! grand mean phenotypes
  End matrices;
 
 Specify G
 20 20 40 40 

 Begin Algebra;
	 R = A+D+E             | H@(X*J')+Q@(W*Y') | H@A     | H@(X*J') _
	     H@(J*X')+Q@(Y*W') | T+U+V             | H@(J*X')| H@T      _
	     H@A               | H@(X*J')          | A+D+E   | F   _
	     H@(J*X')          | H@T               | F       | T+U+V    ;
 End Algebra;

   Means G ;			
   Covariances					! ADE
	 B.R	;

st 10 G 1 1 - G 1 nvarnsib
End

G7: OSFM twins, datagroup
 Data  NInput_vars= 13			
 Missing=-1.00					
 REctangular file=TYPEAMX.dat			
 LABELS     
 zygos jas1 jas2 jasf jasm sex1 sex2 sexf sexm age1 age2 agef agem  	
 Select if  zygos = 6 ; 		! select dosfm	
 Select   jas1 jas2 jasf jasm   ;

    Matrices = group 1 
      G Full 1 nvarnsib free				! grand mean phenotypes
   End matrices;

 Specify G
 20 20 40 40

 Begin Algebra;
	 R = T+U+V             | H@(J*X')+Q@(Y*W') | H@(J*X')| H@T     _
	     H@(X*J')+Q@(W*Y') | A+D+E             | H@A     | H@(X*J')_	
	     H@(X*J')          | H@A               | A+D+E   | F   _
	     H@T               | H@(J*X')          | F       | T+U+V    ;
End Algebra;

   Means G  ;			
   Covariances					! ADE
	 B.R	;

st 10 G  1 1 - G  1 nvarnsib
End

G8: summarize relevant statistics MALES
Data Calc
 Begin Matrices ;
     A  computed nvar nvar = A1
     D  computed nvar nvar = D1
     E  computed nvar nvar = E1
     S full 1 1 = S1	
 End Matrices ;
 Begin Algebra ;
    V = A%(A+D+E) | D%(A+D+E) | E%(A+D+E) ;	! standardized variance components males
 End ALgebra ;
End

G9: Summarize relevant statistics females
Data Calc
 Begin Matrices ;
     A  computed nvar nvar = T1
     D  computed nvar nvar = U1
     E  computed nvar nvar = V1 
 End Matrices ;
 Begin Algebra ;
    V = A%(A+D+E) | D%(A+D+E) | E%(A+D+E) ;	! standardized variance components females
 End ALgebra ;

!Option Multiple issat  		 ! allows comparison of submodels with present model 
End