! PHENOTYPIC GROWTH CURVE MODEL

#define NT 4	  ! number of timepoints.
#define NF 2    	  ! number of factors.



GROUP #1 Initialization
CALCULATION NG=2
BEGIN MATRICES;
	F FULL   NT NF FIXED	! matrix of factor loadings
  	M SYM    NF NF FREE  	! covariance matrix of intercept and slope
  	R DI     NT NT FREE  		! residual variance.
	Q FULL   NF 1 FREE 		! mean intercept & slope 
	N FULL   1  NT FREE 	! Effect of covariate
END MATRICES;

MATRIX F
  1 0
  1 2
  1 3
  1 4.5

ST -.5 N 1 1 - N 1 NT
ST 10 Q 1 1 
ST -1 Q 2 1
ST 10 M 1 1
ST .3 M 2 2
ST -1 M 1 2
ST 5 R 1 1 R 2 2 R 3 3 R 4 4

!BOUND -100 100 ALL



END

GROUP #2 Data
Data NInput_vars= 21			! nr of inputvars per family
 Missing=-1.00			
 REctangular file=aggression.dat		

	LABELS     
	id TWZYG ZYG2
 	NYAGG1.1 NYAGG3.1 NYAGG4.1 NYAGG5.1 
	NYAGG1.2 NYAGG3.2 NYAGG4.2 NYAGG5.2 
	AGE1.1 AGE3.1 AGE4.1 AGE5.1 
	AGE1.2 AGE3.2 AGE4.2 AGE5.2
	AGE91.1 AGE91.2			! tell Mx what is found in the datafile
  
  Select    NYAGG1.1 NYAGG3.1 NYAGG4.1 NYAGG5.1 
                 AGE1.1 AGE3.1 AGE4.1 AGE5.1;	
 Definition AGE1.1 AGE3.1 AGE4.1 AGE5.1;

 BEGIN MATRICES = GROUP 1
	K FULL  1  NT
 END MATRICES;

Specify K
 AGE1.1 AGE3.1 AGE4.1 AGE5.1 


MEANS (F*Q)' + K.N  ;
COVARIANCE F&M + R ;
OPTIONS RS
OPTION SAT = 37564.576,6878 
!OPTION MULTIPLE ISSAT
END

/*
SAVE PHENGROW.MXS
END

GET PHENGROW.MXS
! TEST IF THE VARIATION IN THE SLOPE IS SIGNIFICANT
Drop M 1 2 2 
End

GET PHENGROW.MXS
!TEST IF THE I-S COVARIANCE IS SIGNIFICANT
Drop M 1 2 1
End

GET PHENGROW.MXS
!TEST IF THE AGE EFFECT VARIES ACROSS SURVEYS
Equate N 1 1 1 N 1 1 2 N 1 1 3 N 1 1 4
End

GET PHENGROW.MXS
!TEST IF THERE IS A SIGNIFICANT CHANGE ACROSS SURVEYS IN THE LEVEL OF AGGRESSION
Drop Q 1 2 1
End

*/